UTDom.xDomPoint

/**
 * xDomPoint.  Base class of Domination Points For Double Domination (DoubleDom) matches.
 * 
 * Writen by Brian 'Snake' Alexander. Copyright(c) 2007-2010 All Rights Reserved.
 */
class xDomPoint extends ControlPoint
   abstract;

delegate ResetCount();

simulated function PostNetReceive()
{
   if( !bScoreReady )
      UpdateTeamEffects(5);
   else if ( ControllingTeam == None )
      UpdateTeamEffects(4);
   else
      UpdateTeamEffects(ControllingTeam.TeamIndex);
}

/**
 * TeamIndex=0 red
 * TeamIndex=1 blue
 * TeamIndex=2 green
 * TeamIndex=3 gold
 * TeamIndex=4 neutral
 * TeamIndex=5 disabled
 */
simulated function UpdateTeamEffects(byte TeamIndex)
{
   local byte i;

   super(DominationObjective).UpdateTeamEffects(TeamIndex);

   if (TeamIndex >= 5)
   {
      // Diabled
      bIsDisabled = True;
      bIsActive = False;

      DomLight.SetEnabled(false);
      DomMesh.SetMaterial(0,DomSkin[5]);
      if (DomLetter != none)
         DomLetter.SetHidden(true);

      if (DomRing != none)
         DomRing.SetHidden(true);
   }
   else
   {
      bIsDisabled = false;
      bIsActive = true;

      i = static.ValidateTeamIndex(TeamIndex);
      DomLight.SetEnabled(true);
      DomLight.SetLightProperties(4, LightColors[i]);
      DomMesh.SetMaterial(0,DomSkin[i]);
      if (DomLetter != none)
      {
         DomLetter.SetDomMaterial(i);
         if ( DomLetter.bHidden )
            DomLetter.SetHidden(false);
      }

      if (DomRing != none)
      {
         DomRing.SetDomMaterial(i);
         if ( DomRing.bHidden )
            DomRing.SetHidden(false);
      }
   }
   bForceNetUpdate = True;
}

function UpdateStatus()
{
   local TeamInfo NewTeam;
   local int OldIndex;

   // who is the current controlling team of this domination point?
   if (ControllingPawn == None)
      NewTeam = None;
   else
      NewTeam = ControllingPawn.PlayerReplicationInfo.Team;

   // do nothing if there is no change in the controlling team (and there is a controlling team)
   if ((NewTeam == ControllingTeam) && (NewTeam != None))
      return;

   // for AI, update DefenderTeamIndex
   OldIndex = DefenderTeamIndex;
   if (NewTeam == None)
   {
      DefenderTeamIndex = 255; // ie. "no team" since 0 is a valid team
      if (HomeBase != none)
         HomeBase.DefenderTeamIndex = 255;
   }
   else
   {
      DefenderTeamIndex = NewTeam.TeamIndex;
      if (HomeBase != none)
         HomeBase.DefenderTeamIndex = NewTeam.TeamIndex;
   }

   if ( bScoreReady && (OldIndex != DefenderTeamIndex) )
      UTGame(WorldInfo.Game).FindNewObjectives(Self);

   // otherwise we have a new controlling team, or the domination point is being re-enabled
   ControllingTeam = NewTeam;
   super(DominationObjective).UpdateStatus();
   if (ControllingTeam != None)
   {
      SetAlarm(true);
   }
   ResetCount();

   if (ControllingTeam == None)
   {
      // goes dark while untouchable (disabled) after a score
      if (!bScoreReady)
         UpdateTeamEffects(5);
      else if (bScoreReady) // goes back to white when neutral again
         UpdateTeamEffects(4);
   }
   else
   {
      UpdateTeamEffects(ControllingTeam.TeamIndex);
   }
}

function ResetPoint(bool IsEnabled)
{
   if ( !bScoreReady && IsEnabled )
      UTGame(WorldInfo.Game).FindNewObjectives(Self);

   bScoreReady = IsEnabled;
   if ( IsEnabled )
   {
      Enable('Touch');
      Enable('UnTouch');
   }
   else
   {
      Disable('Touch');
      Disable('UnTouch');
   }

   ControllingPawn = None;
   ControllingTeam = None;
   HolderPRI = None;
   UpdateStatus();
   bForceNetUpdate = True;
}

simulated function SetAlarm(bool bNowOn)
{
   super.SetAlarm(bNowOn);
   if (WorldInfo.NetMode != NM_DedicatedServer)
   {
      if (bNowOn)
      {
         if (AlarmSound != none)
         {
            SetTimer(5.0,false);
            AlarmSound.Play();
         }
      }
      else
      {
         if (AlarmSound != none)
            AlarmSound.Stop();
      }
   }
}

/**
 * don't call super here since we don't want it incrementing score! 
 */
simulated function Timer()
{
   SetAlarm(false);
}

simulated function vector GetHUDOffset(PlayerController PC, Canvas Canvas)
{
   local float Z;

   Z = 60;
   if ( PC.ViewTarget != None )
   {
      Z += 0.1 * VSize(PC.ViewTarget.Location - Location);
   }
   return Z*vect(0,0,1);
}

DefaultProperties
{
   DomSkin[0]=Material'DOM_Content.Materials.DDom.DomPoint_Red_Mat'
   DomSkin[1]=Material'DOM_Content.Materials.DDom.DomPoint_Blue_Mat'
   DomSkin[2]=Material'DOM_Content.Materials.DDom.DomPoint_Green_Mat'
   DomSkin[3]=Material'DOM_Content.Materials.DDom.DomPoint_Gold_Mat'
   DomSkin[4]=Material'DOM_Content.Materials.DDom.DomPoint_Neutral_Mat'
   DomSkin[5]=Material'DOM_Content.Materials.DDom.DomPoint_Disabled_Mat'
   Begin Object Name=CollisionCylinder
      CollisionRadius=+70.0
   End Object
   CollisionType=COLLIDE_TouchAll
   CollisionComponent=CollisionCylinder
   Components.Add(CollisionCylinder)
   Begin Object Name=StaticMeshComponent0
      StaticMesh=StaticMesh'DOM_Content.Meshes.DomPointBaseLower'
      Translation=(X=0.0,Y=0.0,Z=-4.0)
      bAcceptsLights=True
      bAcceptsDynamicLights=True
      LightingChannels=(BSP=True,Dynamic=True,Static=True)
      LightEnvironment=DomPointLightEnvironment
   End Object
   DomMesh=StaticMeshComponent0
   Components.Add(StaticMeshComponent0)
   Begin Object Class=AudioComponent Name=AlarmSoundComponent
      SoundCue=SoundCue'A_Gameplay.CTF.Cue.A_Gameplay_CTF_FlagAlarm_Cue'
   End Object
   AlarmSound=AlarmSoundComponent
   ControlSound=None
   MessageClass=None
   Physics=PHYS_None
   RotationRate=(Yaw=0)
   DesiredRotation=(Yaw=0)
   bHidden=False
   DrawScale=0.6
   EffectOffset=(X=0.0,Y=0.0,Z=40.0)
}