UTDom.xDomTimerMessage

/**
 * DoubleDom Game Count Down Announcements
 * 
 * Writen by Brian 'Snake' Alexander. Copyright(c) 2007-2010 All Rights Reserved.
 *
 * @param Switch:  see list below
 * 18 - RedTeamDominating
 * 19 - BlueTeamDominating
 * 20 - Averted
 * 21 - LastSecondSave
 * 22 - NewRoundIn
 * 30 - Plays Scored music
 */
class xDomTimerMessage extends UTTimerMessage;

static simulated function ClientReceive( PlayerController P, optional int Switch, optional PlayerReplicationInfo RelatedPRI_1,
               optional PlayerReplicationInfo RelatedPRI_2, optional Object OptionalObject )
{
   local AudioComponent CurrentAnnouncementComponent;
   local UTHUD HUD;

   if ( switch == 30 )
   {
      UTPlayerController(P).ClientMusicEvent(14);
      return;
   }
   super(UTLocalMessage).ClientReceive(P, Switch, RelatedPRI_1, RelatedPRI_2, OptionalObject);

   if ( default.Announcements[Switch].AnnouncementSound != None )
   {
      HUD = UTHUD(P.myHUD);
      if ( (HUD != None) && HUD.bIsSplitScreen && !HUD.bIsFirstPlayer )
      {
         return;
      }

      if ( switch > 17 || switch < 30 || Switch < 9 )
      {
         // don't prioritize final countdown with other announcements
         CurrentAnnouncementComponent = P.CreateAudioComponent(SoundCue'A_Announcer_Reward_Cue.SoundCues.AnnouncerCue', false, false);

         // CurrentAnnouncementComponent will be none if -nosound option used
         if ( CurrentAnnouncementComponent != None )
         {
            CurrentAnnouncementComponent.SetWaveParameter('Announcement', default.Announcements[Switch].AnnouncementSound);
            //AnnouncerSoundCue.Duration = default.Announcements[Switch].AnnouncementSound.Duration;
            CurrentAnnouncementComponent.bAutoDestroy = true;
            CurrentAnnouncementComponent.bShouldRemainActiveIfDropped = true;
            CurrentAnnouncementComponent.bAllowSpatialization = false;
            CurrentAnnouncementComponent.bAlwaysPlay = TRUE;
            CurrentAnnouncementComponent.Play();
         }
      }
      else
      {
         UTPlayerController(P).PlayAnnouncement(default.class, Switch);
      }
   }
}

static function string GetString( optional int Switch, optional bool bPRI1HUD, optional PlayerReplicationInfo RelatedPRI_1,
               optional PlayerReplicationInfo RelatedPRI_2, optional Object OptionalObject )
{
   if (Switch == 30)
   {
      return "";
   }

   return default.Announcements[Switch].AnnouncementText;
}

DefaultProperties
{
   Lifetime=2
   Announcements[18]=(AnnouncementSound=SoundNodeWave'A_Announcer_Status.Status.A_StatusAnnouncer_RedTeamDominating')
   Announcements[19]=(AnnouncementSound=SoundNodeWave'A_Announcer_Status.Status.A_StatusAnnouncer_BlueTeamDominating')
   Announcements[20]=(AnnouncementSound=SoundNodeWave'A_Announcer_Status.Status.A_StatusAnnouncer_Averted')
   Announcements[21]=(AnnouncementSound=SoundNodeWave'A_Announcer_Status.Status.A_StatusAnnouncer_LastSecondSave')
   Announcements[22]=(AnnouncementSound=SoundNodeWave'A_Announcer_Status.Status.A_StatusAnnouncer_NewRoundIn')
}