UTMultiTeam.UTMT_TeamInfo

//-----------------------------------------------------------
// Copyright 2007, Infinity Impossible
//-----------------------------------------------------------
class UTMT_TeamInfo extends UTTeamInfo
   dependson(UTMT_TeamMaterialTransformer);


/** The color of the indexed team's HUD icons */
var array<LinearColor> TeamImageColors;
/** The color of the indexed team's HUD text in team beacons above people's heads */
var array<color> TeamTextColors;
/** The color of the indexed team's say lines in chat */
var array<color> TeamSayColors;


/**
 * The transforms performed on characters' skins for the index team.
 * See UTMT_TeamMaterialTransformer for more information.
 */
var array<UTMT_TeamMaterialTransformer.TeamColorTransform> CharacterTeamColorTransforms;


/**
 * The transforms performed on vehicles' skins for the index team.
 * See UTMT_TeamMaterialTransformer for more information.
 *
 * Note: not yet implemented.
 */
var array<UTMT_TeamMaterialTransformer.TeamColorTransform> VehicleTeamColorTransforms;


var UTMT_TeamMaterialTransformer CharacterTeamMaterialTransformer;
var UTMT_TeamMaterialTransformer VehicleTeamMaterialTransformer;


replication
{
   if(Role == ROLE_Authority)
      CharacterTeamMaterialTransformer, VehicleTeamMaterialTransformer;
}


static simulated function UTMT_TeamInfo GetPawnMultiTeamInfo(Pawn P)
{
   local UTMT_Pawn UTMTP;
   local UTMT_TeamInfo MultiTeamInfo;

   UTMTP = UTMT_Pawn(P);

   if(UTMTP != None)
      MultiTeamInfo = UTMT_TeamInfo(UTMTP.GetTeam());

   return MultiTeamInfo;
}


simulated function LinearColor GetImageColor()
{
   return TeamImageColors[TeamIndex];
}


static simulated function LinearColor GetDefaultImageColor(int DefaultTeamIndex)
{
   return default.TeamImageColors[DefaultTeamIndex];
}


simulated function color GetTextColor()
{
   return TeamTextColors[TeamIndex];
}


static simulated function color GetDefaultTextColor(int DefaultTeamIndex)
{
   return default.TeamTextColors[DefaultTeamIndex];
}


simulated function string GetTeamCaption(optional bool bWithSpacing=True)
{
   local string PreCaption;

   if(bWithSpacing)
      PreCaption = " ";

   return PreCaption$TeamColorNames[TeamIndex]@"Team";
}


simulated function color GetTeamSayColor()
{
   return TeamSayColors[TeamIndex];
}


static simulated function color GetDefaultTeamSayColor(int DefaultTeamIndex)
{
   return default.TeamSayColors[DefaultTeamIndex];
}


simulated function LinearColor GetShieldBeltColor()
{
   local LinearColor From;
   local int Hue;

   From = CharacterTeamMaterialTransformer.RedMask;
   Hue = CharacterTeamColorTransforms[TeamIndex].Hue;

   return MakeLinearColor(-800, -800, -800, 0) - ( (CharacterTeamMaterialTransformer.HueTransform(From, Hue)) * (-1200.0) );
}


simulated function TransformCharacterMaterial(MaterialInstanceConstant OldMIC)
{
   assert(CharacterTeamColorTransforms.Length > TeamIndex);
   CharacterTeamMaterialTransformer.TransformMaterial(OldMIC, CharacterTeamColorTransforms[TeamIndex]);
}


simulated function TransformVehicleMaterial(MaterialInstanceConstant OldMIC)
{
   assert(VehicleTeamColorTransforms.Length > TeamIndex);
   VehicleTeamMaterialTransformer.TransformMaterial(OldMIC, VehicleTeamColorTransforms[TeamIndex]);
}

defaultproperties
{
   TeamImageColors(0)=(R=3.000000,G=0.000000,B=0.050000,A=0.800000)
   TeamImageColors(1)=(R=0.500000,G=0.800000,B=10.000000,A=0.800000)
   TeamImageColors(2)=(R=1.000000,G=4.000000,B=1.000000,A=0.800000)
   TeamImageColors(3)=(R=4.000000,G=4.000000,B=0.000000,A=0.800000)
   TeamTextColors(0)=(B=128,G=255,R=255,A=255)
   TeamTextColors(1)=(B=128,G=255,R=255,A=255)
   TeamTextColors(2)=(B=128,G=255,R=255,A=255)
   TeamTextColors(3)=(B=128,G=255,R=255,A=255)
   TeamSayColors(0)=(B=64,G=64,R=255,A=255)
   TeamSayColors(1)=(B=255,G=192,R=64,A=255)
   TeamSayColors(2)=(B=0,G=192,R=0,A=255)
   TeamSayColors(3)=(B=64,G=255,R=255,A=255)
   CharacterTeamColorTransforms(0)=(R=1.000000,G=1.000000,B=1.000000,VectorParams=((ParamName="Char_TeamColor",ParamValue=(R=2.000000,G=0.000000,B=0.000000,A=2.000000)),(ParamName="Char_Emissive_Color",ParamValue=(R=1.000000,G=0.000000,B=0.000000,A=1.000000))))
   CharacterTeamColorTransforms(1)=(Hue=240.000000,R=1.000000,G=1.000000,B=1.000000,VectorParams=((ParamName="Char_TeamColor",ParamValue=(R=0.000000,G=0.000000,B=2.000000,A=2.000000)),(ParamName="Char_Emissive_Color",ParamValue=(R=0.000000,G=0.000000,B=1.000000,A=1.000000))))
   CharacterTeamColorTransforms(2)=(Hue=120.000000,R=1.000000,G=1.000000,B=1.000000,VectorParams=((ParamName="Char_TeamColor",ParamValue=(R=0.500000,G=2.000000,B=0.500000,A=1.000000)),(ParamName="Char_Emissive_Color",ParamValue=(R=0.250000,G=1.000000,B=0.250000,A=1.000000))))
   CharacterTeamColorTransforms(3)=(Hue=60.000000,R=1.200000,G=1.200000,B=1.200000,VectorParams=((ParamName="Char_TeamColor",ParamValue=(R=2.000000,G=2.000000,B=0.000000,A=2.000000)),(ParamName="Char_Emissive_Color",ParamValue=(R=1.000000,G=1.000000,B=0.000000,A=1.000000))))
   VehicleTeamColorTransforms(0)=(R=1.000000,G=1.000000,B=1.000000,VectorParams=((ParamName="Team_Color_Glow",ParamValue=(R=2.000000,G=0.000000,B=0.000000,A=2.000000)),(ParamName="Veh_Plating_Team_Color",ParamValue=(R=2.000000,G=0.000000,B=0.000000,A=2.000000))))
   VehicleTeamColorTransforms(1)=(Hue=240.000000,R=1.000000,G=1.000000,B=1.000000,VectorParams=((ParamName="Team_Color_Glow",ParamValue=(R=0.000000,G=0.000000,B=2.000000,A=2.000000)),(ParamName="Veh_Plating_Team_Color",ParamValue=(R=0.000000,G=0.000000,B=2.000000,A=2.000000))))
   VehicleTeamColorTransforms(2)=(Hue=80.000000,R=0.500000,G=0.500000,B=0.500000,VectorParams=((ParamName="Team_Color_Glow",ParamValue=(R=0.100000,G=0.500000,B=0.000000,A=1.000000)),(ParamName="Veh_Plating_Team_Color",ParamValue=(R=0.100000,G=0.500000,B=0.000000,A=1.000000))))
   VehicleTeamColorTransforms(3)=(Hue=40.000000,R=1.200000,G=1.200000,B=1.200000,VectorParams=((ParamName="Team_Color_Glow",ParamValue=(R=1.000000,G=1.000000,B=0.000000,A=2.000000)),(ParamName="Veh_Plating_Team_Color",ParamValue=(R=1.000000,G=1.000000,B=0.000000,A=2.000000))))
}