UTMultiTeam.UTMT_UTUIScene_MidGameMenu

//-----------------------------------------------------------
// Copyright 2007, Infinity Impossible
//-----------------------------------------------------------
class UTMT_UTUIScene_MidGameMenu extends UTUIScene_MidGameMenu;


const MIN_TEAM_OPTION_BUTTONS = 2;
const MAX_TEAM_OPTION_BUTTONS = 3;

var array<name> ChangeTeamTabPageNames;

var localized string ChangeTeamTitle;
var localized string ChangeTeamMessage;


function SetupButtonBar()
{
	local int ChangeTeamButtonIndex;
	local WorldInfo WI;
	local UTGameReplicationInfo GRI;
	local int i;

	WI = GetWorldInfo();
	Super.SetupButtonBar();

	InGamePage = UTUITabPage_InGame(FindChild('GameTab',true));

 	// Take a guess at which is the "Change Team" button. Uses the same logic as
 	// the UIUITabPage_InGame class does to determine if such exists.
 	if(	ButtonBar != None )
 	{
		if ( WI != none )
		{
			GRI = UTGameReplicationInfo(WI.GRI);
			if ( GRI != none && GRI.CanChangeTeam() )
			{
				for(i=0; i<ChangeTeamTabPageNames.Length; ++i)
				{
					if(ChangeTeamTabPageNames[i] == TabControl.ActivePage.WidgetTag)
					{
		        	    ChangeTeamButtonIndex = (InGamePage.RulesButtonIndex - 1);
		        	    if(ChangeTeamButtonIndex > 0)
							ButtonBar.SetButton(ChangeTeamButtonIndex, "<Strings:UTGameUI.ButtonCallouts.ChangeTeam>", OnChangeTeam);
						break;
					}
				}
	 	    }
	    }
	 }
}


function ShowChangeTeamMBScene(PlayerController PC, array<string> TeamNames)
{
	local int i;
	local int pos;

	MBScene = GetMessageBoxScene();
	if(MBScene != none)
	{
		pos = 0;

		MBScene.PotentialOptions.Length = 1 + (GetWorldInfo().GRI.Teams.Length-1);

		for(i = 0; i < GetWorldInfo().GRI.Teams.Length; ++i)
		{
			if(i != PC.PlayerReplicationInfo.Team.TeamIndex)
			{
				if(TeamNames.Length > i)
				{
					MBScene.PotentialOptions[pos] = TeamNames[i];
				}
				else
				{
					MBScene.PotentialOptions[pos] = "Team"@i;
				}

				++pos;
			}
		}

		MBScene.PotentialOptions[pos] = MBScene.CANCEL_BUTTON_MARKUP_STRING;
		MBScene.PotentialOptionKeyMappings.length = pos + 1;
		MBScene.PotentialOptionKeyMappings[pos].Keys.length = 2;
		MBScene.PotentialOptionKeyMappings[pos].Keys[0]='XboxTypeS_B';
		MBScene.PotentialOptionKeyMappings[pos].Keys[1]='Escape';

		  TabControl.PlayUIAnimation('FadeOut',,5.0);
		ButtonBar.PlayUIAnimation('FadeOut',,5.0);

		MBScene.Display(ChangeTeamMessage, ChangeTeamTitle, MB_ChangeTeamSelection, pos);
	}
}


/**
 * Displays a menu for the player if there are the right number of teams (2 or 3).
 * This is because using the message box scene is a slight hack - it only has
 * room for 4 buttons. If the box cannot be display correctly, just go with
 * a team change regardless of any user preference!
 */
function bool OnChangeTeam(UIScreenObject InButton, int InPlayerIndex)
{
	local LocalPlayer LP;
	local UTMT_PlayerController MTPC;
	local int NumOtherTeams;

		LP = GetPlayerOwner(InPlayerIndex);
	if ( LP != none && LP.Actor != none )
	{
		  MTPC = UTMT_PlayerController(LP.Actor);
		  if(MTPC != None)
		  {
		  	NumOtherTeams = GetWorldInfo().GRI.Teams.Length - 1;

		  	// Display the menu for changing teams if there are enough buttons,
		  	// otherwise just move the player on to the next possible team.
		 		if( (NumOtherTeams <= MAX_TEAM_OPTION_BUTTONS)
			   	&& (NumOtherTeams >= MIN_TEAM_OPTION_BUTTONS) )
			{
				ShowChangeTeamMBScene(MTPC, MTPC.TeamNames);
			}
			else
			{
				MTPC.SwitchTeam();
				CloseScene(self);
			}
		}
		else
		{
			WarnInternal("No UTMultiTeamPlayercontroller found");
		}
	}
	return true;
}


function MB_ChangeTeamSelection(UTUIScene_MessageBox MessageBox, int SelectedOption, int PlayerIndex)
{
	local LocalPlayer LP;
	local UTMT_PlayerController MTPC;

	TabControl.PlayUIAnimation('FadeIn',,5.0);
	ButtonBar.PlayUIAnimation('FadeIn',,5.0);

		LP = GetPlayerOwner(PlayerIndex);
	if( LP != none && LP.Actor != none )
	{
		if( SelectedOption != MessageBox.FindCancelButtonIndex() )
		{
			MTPC = UTMT_PlayerController(LP.Actor);
		  	if(MTPC != None)
		  	{
				 	//TODO: Fix this to work with localization markup
				MTPC.ChangeTeam(MBScene.PotentialOptions[SelectedOption]);
				CloseScene(self);
			}
			else
			{
				WarnInternal("No UTMultiTeamPlayercontroller found");
			}
		}
	}
}

defaultproperties
{
	ChangeTeamTabPageNames(0)="GameTab"
	ChangeTeamTabPageNames(1)="ScoreTab"
	ChangeTeamTitle="Change Team"
	ChangeTeamMessage="Choose your new affiliation, traitorous dog. Be strong, for soon come unto you the untold wrath of ye former teammates and lo, shall it be swift and painful."
}